/*
TimeTrial Gamemode for Shootmania
Copyright (C) 2013 TGYoshi

This program is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program.  If not, see <http://www.gnu.org/licenses/>.
*/

#RequireContext CSmMode
#Include "Libs/Nadeo/Mode.Script.txt"
#Include "MathLib" as MathLib
#Include "TextLib" as TextLib
#Include "Libs/Nadeo/ShootMania/SM.Script.txt" as SM
#Include "Libs/Nadeo/ShootMania/Score.Script.txt" as Score
#Const	CompatibleMapTypes	"TimeTrial"
#Const	Version				"V3.4-beta public"
#Const MatchTime			1500000	
#Const SpawnInterval			5	
#Const C_UITickPeriod			200

Text GetTime(Integer StartTime) {
	declare Text r = TextLib::TimeToText(Now-StartTime);
	declare Text b = TextLib::ToText(Now-StartTime);
	r ^= "."^TextLib::SubString(b, TextLib::Length(b)-3, 3);
	return r;
}
Text GetTime2(Integer RealTime) {
	declare Text r = TextLib::TimeToText(RealTime);
	declare Text b = TextLib::ToText(RealTime);
	r ^= "."^TextLib::SubString(b, TextLib::Length(b)-3, 3);
	return r;
}
Void ThrowMessage(Text msg, Boolean notice) {
	if (notice) {
		UIManager.UIAll.SendNotice(msg, 
				CUIConfig::ENoticeLevel::MatchInfo, Null, 
				CUIConfig::EAvatarVariant::Default, 
				CUIConfig::EUISound::TieBreakPoint, 0);
	} else {
		UIManager.UIAll.BigMessage = msg;
	}
}
Text MLGet_ScoreTable(Boolean ShowLP) {
	declare ML = "";
	declare List = "";
		declare i = 0;
		declare CSmPlayer[] Listed;
	declare CSmPlayer[] AllPlayers;
	foreach (Player in Players) {
		AllPlayers.add(Player);
	}
	foreach (Player in Spectators) {
		AllPlayers.add(Player);
	}
	declare height = (AllPlayers.count)/2;
	if (height * 2 != AllPlayers.count)
		height += 1;
	if (height < 8)
		height = 8;
	foreach (Score in Scores) {
		foreach (Player in AllPlayers) {
			if (Score.Points != Player.Score.Points || Listed.exists(Player))
				continue;
			Listed.add(Player);
			//for (j, 1, 5) {
			i+=1;
			declare Integer BestTime for Player;
			declare Integer BestResp for Player;
			declare Text LPMsg = "";
			if (ShowLP) {
				if (Player.Score.IsRegisteredForLadderMatch)
					LPMsg = "$faa$o+"^Player.Score.LadderScore^" LP";
				else
					LPMsg = "$faa$o(unofficial)";
			}
			declare wpos = "1";
			declare hpos = ""^-7*i-1;
			if (i > height) {
				wpos = "81";
				hpos = ""^-7*(i-height)-1;
			}
			List ^= """<frame posn="{{{wpos}}} {{{hpos}}} 1">
			<quad posn="2 0 1" sizen="78 6.5" style="BgsPlayerCard" substyle="BgCard" scriptevents="1" id="{{{Player.Login}}}"/>
			<label posn="50 -4 2" sizen="50 8" scale="0.6" text="{{{LPMsg}}}" halign="right" />""";
			List ^= """<label posn="10 0 2" sizen="50 8" scale="0.9" text="{{{TextLib::MLEncode(Player.Name)}}}" />""";
			if (Player.Score.Points < 2) {
				List ^= """
				<label posn="4 -1 2" sizen="50 8" scale="1" text="$o-." />
				<label posn="78 -3.5 2" sizen="50 8" scale="0.5" text="Respawns: $o-" halign="right" />
				<label posn="78 0 2" sizen="50 8" scale="0.7" text="$o-:--.---" halign="right" />""";

			} else {
				if (i > 3) List ^= """<label posn="4 -1 2" sizen="50 8" scale="0.9" text="$o{{{i}}}." />""";
				if (i == 3) List ^= """<quad posn="6 -3.5 2" sizen="6 6" halign="center" valign="center" style="Icons64x64_1" substyle="Third" />""";
				if (i == 2) List ^= """<quad posn="6 -3.5 2" sizen="6 6" halign="center" valign="center" style="Icons64x64_1" substyle="Second" />""";
				if (i == 1) List ^= """<quad posn="6 -3.5 2" sizen="6 6" halign="center" valign="center" style="Icons64x64_1" substyle="First" />""";
				List ^= """<label posn="78 -3.5 2" sizen="50 8" scale="0.5" text="Respawns: {{{BestResp}}}" halign="right" />
				<label posn="78 0 2" sizen="50 8" scale="0.7" text="$o{{{GetTime2(100000000-Player.Score.Points)}}}" halign="right" />""";
			}
			declare RankOffset = "10";
			declare Training for Player = False;
			if (Spectators.exists(Player)) {
				/*List ^= """
					<label posn="110 0 2" sizen="50 8" scale="0.5" text="$o$aaaSpectating" halign="center" />
				""";*/
				List ^= """<quad posn="12 -5 31" sizen="5 5" halign="center" valign="center" style="Icons64x64_1" substyle="CameraLocal" />""";
				RankOffset = "16";
			} else if (Training) {
				List ^= """<quad posn="12 -5.5 31" sizen="4 4" halign="center" valign="center" style="Icons128x128_1" substyle="Race" />""";
				RankOffset = "16";
			}
			if (Player.User.LadderRank != -1)
			List ^= """
				<label posn="{{{RankOffset}}} -4 2" sizen="50 8" scale="0.5" text="Rank: $o{{{Player.User.LadderRank}}}" halign="left"/>
				""";
			else
			List ^= """
				<label posn="{{{RankOffset}}} -4 2" sizen="50 8" scale="0.5" text="$oUnranked" halign="left"/>
				""";
			List ^= """</frame>""";
			//}
			break;
		}
	}
		ML = """
		<frame posn="-82 {{{(10+height*7)/2}}}">
			<quad posn="0 0 1" sizen="164 {{{10+height*7}}}" style="Bgs1InRace" substyle="BgList"/>
			<label posn="82 -2 2" sizen="50 8" style="TextRankingsBig" scale="0.8" text="Scoretable" halign="center" />
			{{{List}}}
		</frame>
		<frame posn="0 0 20" id="MenuFrame">
			<quad bgcolor="234A" sizen="40 16" id="_PMenu" scriptevents="1"/>
			<label text="Spectate" posn="2 -2 21" style="CardButtonSmall" id="_Spectate" scriptevents="1"/>
			<label text="Player card" posn="2 -8 21" style="CardButtonSmall" id="_Card" scriptevents="1"/>
		</frame>
		<script><!--
			
			#Include "TextLib" as TextLib
			main () {
				declare netwrite Net_SpecTargetReq for UI = "";
				declare netwrite Integer Net_SpecTargetCn for UI = 0;
				declare CMlFrame MenuFrame <=> (Page.GetFirstChild("MenuFrame") as CMlFrame);
				declare MenuTarget = "";
				declare Boolean[Text] SpectateStates;
				MenuFrame.Hide();
				while(True) {
					foreach(Event in PendingEvents)	{
						switch(Event.Type){
							case CMlEvent::Type::MouseClick: {
								if (Event.ControlId == "_Spectate") {
									if (MenuTarget == "")
										continue;
									Spectate(MenuTarget);
									Net_SpecTargetReq = MenuTarget;
									Net_SpecTargetCn = Now;
									MenuFrame.Hide();
								} else if (Event.ControlId == "_Card") {
									if (MenuTarget == "")
										continue;
									MenuFrame.Hide();
									ShowProfile(MenuTarget);
								} else {
									MenuFrame.PosnX = MouseX-2.;
									MenuFrame.PosnY = MouseY+2.;
									MenuFrame.Show();
									MenuTarget = Event.ControlId;
								}
							}
							case CMlEvent::Type::MouseOut: {
								//if (Event.ControlId == "_PMenu") // works quite bad
								//	MenuFrame.Hide();
							}
							case CMlEvent::Type::KeyPress:
							{
							}
						}
					}
					if (MouseX - MenuFrame.PosnX < -5 || MouseY - MenuFrame.PosnY < -21 ||
						MouseX - MenuFrame.PosnX > 45 || MouseY - MenuFrame.PosnY > 5)
							MenuFrame.Hide();
					yield;
				}
			}
		--></script>
	""";
		return ML;
}
Text MLGet_Info() {
	declare ML = "";
		ML = """
		<frame posn="156 -85 0">
			<!--<label posn="0 0 1" scale="1.1" halign="right" style="TextButtonNav" text="Some status message." />	-->	
		</frame>
	""";
		return ML;
}
Text MLGet_SpawnScreen(Text MapName, Text MapCreator) {
	declare Text ML;
	ML = """
		<script><!--
			
			#Include "TextLib" as TextLib
			Real Abs(Integer a) { // also real conv. well it's not really absolute anymore :P:P:P
				if (a < 0)
					return 0.0;
				return TextLib::ToReal(TextLib::ToText(a))*0.7;
			}
			main () {
			""";
			for (i, 1, 18) {
				ML ^= """declare L{{{i}}} <=> Page.GetFirstChild("L{{{i}}}");""";
				ML ^= """declare R{{{i}}} <=> Page.GetFirstChild("R{{{i}}}");""";
			}
			ML ^= """
				while (True) {
					for (i, 1, 54) {
						sleep(25);""";
						for (i, 1, 18) {
							ML ^= """L{{{i}}}.Scale = Abs(i-{{{i*3}}})/3;""";
							ML ^= """R{{{i}}}.Scale = Abs(i-{{{i*3}}})/3;""";
						}
					ML ^= """}
					for (i, 1, 10) {
						sleep(25);""";
						for (i, 1, 18) {
							ML ^= """L{{{i}}}.Scale = Abs({{{18-i}}})*(Abs(10-i)/8);""";
							ML ^= """R{{{i}}}.Scale = Abs({{{18-i}}})*(Abs(10-i)/8);""";
						}
					ML ^= """}
					yield;
				}
			}
		--></script>
		<frame posn="0 0 1">""";
			for (i, 1, 18)
				ML ^= """<label posn="-130 {{{i*10-95}}} 2" scale="5" halign="center" valign="center" style="TextTitle3" text="$fff$w^" id="L{{{i}}}"/>""";
			for (i, 1, 18)
				ML ^= """<label posn="130 {{{i*10-95}}} 2" scale="5" halign="center" valign="center" style="TextTitle3" text="$fff$w^" id="R{{{i}}}"/>""";
		ML ^= """
			<label posn="0 65 2" scale="1.8" halign="center" valign="center" text="$o$08fWelcome to"/>
			<label posn="0 50 2" scale="6" halign="center" valign="center" text="$o$08fTimeTrial"/>
			<label posn="0 -20 2" scale="2.5" halign="center" valign="center" text="$o$fffCurrent map:"/>
			<label posn="0 -35 2" scale="2" halign="center" valign="center" text="{{{TextLib::MLEncode(MapName)}}}"/>
			<label posn="0 -60 2" scale="2.5" halign="center" valign="center" text="$o$fffBuilt by:"/>
			<label posn="0 -75 2" scale="2" halign="center" valign="center" text="{{{TextLib::MLEncode(MapCreator)}}}"/>
			</frame>""";
	return ML;
}
Text MLGet_Gui(Integer UIType, Integer CPCount, Boolean TrainingState, Boolean ShowTraining, Integer CurrentCP) {
	// {todo} Cleaner way to do this. This works quite well actually, but it's ugly.
	declare Text ML;
	declare TimerUIh = "80";
	declare SpecCUIh = "-35";
	declare SpecTUIh = "-35";
	if (UIType >= 2) // Global overlook/FreeCam 
		TimerUIh = "200";
	if (UIType != 0) // No player
		SpecCUIh = "200";
	if (UIType == 0) // Player (no spec ui)
		SpecTUIh = "200";
	declare ColWindow = "5";
	if (TrainingState)
		ColWindow = "1";
	ML = """
		<script><!--
			
			#Include "TextLib" as TextLib
			main () {
				declare FrameRules	<=> Page.GetFirstChild("FrameRules");
				declare CGameManialinkLabel FrameTime <=> (Page.GetFirstChild("FrameTime") as CGameManialinkLabel);
				declare CGameManialinkLabel FrameResp <=> (Page.GetFirstChild("FrameResp") as CGameManialinkLabel);
				declare CGameManialinkLabel SpecCount <=> (Page.GetFirstChild("SpecCount") as CGameManialinkLabel);
				declare CGameManialinkLabel SpecCount2 <=> (Page.GetFirstChild("SpecCount2") as CGameManialinkLabel);
				declare CGameManialinkQuad Co <=> (Page.GetFirstChild("Co") as CGameManialinkQuad);
				declare CGameManialinkLabel CPI1 <=> (Page.GetFirstChild("CPI1") as CGameManialinkLabel);
				declare CGameManialinkLabel CPI2 <=> (Page.GetFirstChild("CPI2") as CGameManialinkLabel);
				declare CGameManialinkLabel CPI3 <=> (Page.GetFirstChild("CPI3") as CGameManialinkLabel);
				declare CGameManialinkQuad Resp1 <=> (Page.GetFirstChild("Resp1") as CGameManialinkQuad);
				declare CGameManialinkLabel Resp2 <=> (Page.GetFirstChild("Resp2") as CGameManialinkLabel);
				declare CMlFrame Training <=> (Page.GetFirstChild("Training") as CMlFrame);
				""";
				if (!ShowTraining)
				ML ^= """Training.Hide();""";
				ML ^= """declare Integer UIType = {{{UIType}}};
				declare Integer Launch = Now+4000;
				declare netread Net_Resp for UI = 0;
				declare netread Net_StartTime for UI = 0;
				declare netread Net_SpecCount for UI = 0;
				declare netwrite Net_Surrender for UI = 0;
				declare netwrite Net_AlwaysFF for UI = False;
				declare netwrite Net_SpecTypePref for UI = 0;
				declare netwrite Net_SpecWhoReq for UI = 0;
				declare netwrite Net_SpecTargetReq for UI = "";
				declare netwrite Integer Net_SpecTargetCn for UI = 0;
				declare netwrite Net_TrainingToggleTime for UI = 0;
				declare netwrite Net_TrainingCP for UI = 0;
				declare netread Net_Copilot for UI = 0;
				declare netread Net_CopilotTime for UI = 0;
				declare netread Net_CpInfo1 for UI = "";
				declare netread Net_CpInfo2 for UI = "";
				declare netread Net_CpInfo3 for UI = "";
				declare netread Net_CpInfoTime for UI = 0;
				Net_Surrender = 0;
					
				while(True) {
					FrameRules.Show();
					if (GameTime > (Net_StartTime)) {
						declare Text r = TextLib::TimeToText(GameTime-Net_StartTime);
						declare Text b = TextLib::ToText(GameTime-Net_StartTime);
						r ^= "."^TextLib::SubString(b, TextLib::Length(b)-3, 3);
						FrameTime.SetText("$fff"^r);""";
						if (!TrainingState)
							ML ^= """FrameResp.SetText("$fffRespawns: "^Net_Resp);""";
						ML ^= """SpecCount.SetText("$fff"^Net_SpecCount);
					}
					if (Net_CopilotTime > GameTime - 3600 && Net_CopilotTime != 0) {
						if (Co.Visible == False && GameTime - Net_CopilotTime > 1500) {
							Co.Show();
							if (Net_Copilot == 0) Co.Substyle = "Up";
							if (Net_Copilot == 1) Co.Substyle = "Left";
							if (Net_Copilot == 2) Co.Substyle = "Right";
							if (Net_Copilot == 3) Co.Substyle = "Down";
						}
					} else if (Co.Visible)
						Co.Hide();
					if (Net_CpInfoTime > GameTime - 4000 && Net_CpInfoTime != 0) {
						if (CPI2.Scale < 1) {
							CPI2.Scale = CPI2.Scale + 0.2;
							CPI1.Scale = CPI2.Scale * 1.5;
							CPI3.Scale = CPI2.Scale;
						}
						CPI1.SetText(Net_CpInfo1);
						CPI2.SetText(Net_CpInfo2);
						CPI3.SetText(Net_CpInfo3);	
					} else if (CPI1.Scale > 0.0) {
						CPI2.Scale = CPI2.Scale - 0.1;
						CPI1.Scale = CPI2.Scale * 1.5;
						CPI3.Scale = CPI2.Scale;
					} else {
						CPI1.Scale = 0.0;
						CPI2.Scale = 0.0;
						CPI3.Scale = 0.0;
					}
					if (UIType == 1) {
						SpecCount2.SetText("$fff"^Net_SpecCount);
					} else if (UIType >= 2) {
						SpecCount2.SetText("$fff-");
					}
					if (Net_AlwaysFF) {
						Resp2.SetText("at start $o(F4)");
						Resp1.Substyle = "FinishGrey";
					} else {
						Resp2.SetText("at CPs $o(F4)");
						Resp1.Substyle = "Finish";
					}
					foreach(Event in PendingEvents)	{
						switch(Event.Type){
					
							case CMlEvent::Type::KeyPress:
							{
								if (Event.CharPressed == "2555904") // F3
								{ // Send respawn request.
									Net_Surrender = GameTime;
								} 
								if (Event.CharPressed == "2621440") // F4
								{
									Net_AlwaysFF = !Net_AlwaysFF;
								}
							}
							case CMlEvent::Type::MouseClick: {
								if (Event.ControlId == "SpecFree") {
									Net_SpecTypePref = 1;
									Net_SpecTargetReq = "";
									Net_SpecTargetCn = Now;
								}
								if (Event.ControlId == "SpecOverview") {
									Net_SpecTypePref = 2;	
									Net_SpecTargetReq = "";
									Net_SpecTargetCn = Now;
								}
								if (Event.ControlId == "SpecWho")
									Net_SpecWhoReq = GameTime;	
								if (Event.ControlId == "OpenTraining")
								{
									if (Training.Visible)
										Training.Hide();
									else
										Training.Show();
								}
								if (Event.ControlId == "ToggleTraining")
									Net_TrainingToggleTime = GameTime;	
								else if (TextLib::SubString(Event.ControlId, 0, 4) == "TCPi") {
									Net_TrainingCP = TextLib::ToInteger(TextLib::SubString(Event.ControlId, 4, TextLib::Length(Event.ControlId)-4))+1;
									Training.Hide();
								}
							}
						}
					}
					yield;
				}
			}
		--></script>
		<frame posn="0 {{{TimerUIh}}} 1" id="FrameRules">
			<frame posn="0 0 5">
				<quad posn="0 0 30" sizen="40 10" halign="center" valign="center" style="Bgs1InRace" substyle="BgTitle3_{{{ColWindow}}}" />
				<label posn="0 0 31" scale="1.5" halign="center" valign="center" style="TextTitle3" text="$fff0:00.000" id="FrameTime" />""";
				if (TrainingState)
				ML ^= """<label posn="0 5 31" scale="0.7" halign="center" valign="center" style="TextTitle3" text="$08fTraining mode" id="FrameResp" />""";
				else
				ML ^= """<label posn="0 5 31" scale="0.7" halign="center" valign="center" style="TextTitle3" text="$fffRespawns: 0" id="FrameResp" />""";
				ML ^= """<quad posn="-23 0 32" sizen="10 10" halign="center" valign="center" style="BgsPlayerCard" substyle="BgPlayerCard" id="OpenTraining" scriptevents="1"/>
				<quad posn="-23 -1 33" sizen="8 8" halign="center" valign="center" style="Icons128x128_1" substyle="Race"/>
			</frame>
			<quad posn="0 -40 32" sizen="20 20" halign="center" valign="center" style="Copilot" substyle="" id="Co"/>
			<label posn="0 -15 31" scale="1.5" halign="center" valign="center" style="TextSubTitle1" text="" id="CPI1" Scale="0.8" />
			<label posn="0 -20 31" scale="1" halign="center" valign="center" text="" id="CPI2" Scale="0.8" />
			<label posn="0 -24 31" scale="1" halign="center" valign="center" text="" id="CPI3" Scale="0.8" />
		</frame>""";
	ML ^= """	
		<frame posn="-158.5 {{{SpecCUIh}}} 1">
			<quad posn="0 0 30" sizen="30 8" halign="center" valign="center" style="BgsPlayerCard" substyle="BgPlayerCard"  id="SpecWho" scriptevents="1"/>
			<quad posn="3 0 31" sizen="8 8" halign="center" valign="center" style="Icons64x64_1" substyle="Camera" />
			<label posn="10 0.5 31" scale="1" halign="center" valign="center" text="0" id="SpecCount" />
			<quad posn="1 -6 31" sizen="8 8" halign="center" valign="center" style="Icons64x64_1" substyle="Finish" id="Resp1" />
			<label posn="4 -4.8 31" scale="0.63" halign="left" valign="center" text="Respawning" />
			<label posn="4 -7.5 31" scale="0.63" halign="left" valign="center" text="at CPs" id="Resp2" />
		</frame>
	""";
	ML ^= """
		<frame posn="0 70 1" id="Training">
			<quad posn="-30 0 1" sizen="60 14" style="Bgs1InRace" substyle="BgList"/>
			<label posn="0 -2 31" halign="center" valign="center" text="$o$08f$sCheckpoint training settings" scale="0.78" />""";
	if (TrainingState && CPCount > 1) {
		ML ^= """
			<label posn="-26 -6.5 31" halign="left" valign="center" text="$o$0f0Enabled" scale="0.7" />
			<label text="Disable CP-Training" posn="-7 -4 21" style="CardButtonSmall" id="ToggleTraining" scriptevents="1"/>
			<label posn="0 -11 31" halign="center" valign="center" text="$oSelect a checkpoint to train below:" scale="0.6" />""";
			for(j, 0, CPCount-1) {
				declare color = "";
				if (j == CurrentCP-1) color = "$5f5";
				ML ^= """<quad posn="{{{j*7.0-((CPCount)*7.0)/2.0}}} -14 1" sizen="6 6" style="BgsPlayerCard" substyle="BgCard" scriptevents="1" id="TCPi{{{j}}}"/><label posn="{{{j*7.0-((CPCount)*7.0)/2.0+3}}} -17 1" sizen="6 6" halign="center" valign="center" text="$o{{{color}}}{{{j}}}" scale="1" />""";
			}
	} else
		ML ^= """
			<label posn="-26 -6.5 31" halign="left" valign="center" text="$o$f00Disabled" scale="0.7" />
			<label text="Enable CP-Training" posn="-7 -4 21" style="CardButtonSmall" id="ToggleTraining" scriptevents="1"/>
			<label posn="0 -11 31" halign="center" valign="center" text="$f00Enabling CP-training will cancel your current run!" scale="0.6" />""";
	ML ^= """	</frame>
	""";
	declare Text TargetC = "";
	declare Text FreeC = "";
	declare Text OverviewC = "";
	if (UIType == 1) TargetC = "$o$adf";
	if (UIType == 3) FreeC = "$o$adf";
	if (UIType == 2) OverviewC = "$o$adf";
	ML ^= """	
		<frame posn="-158.5 {{{SpecTUIh}}} 1">
			<quad posn="0 0 30" sizen="30 8" halign="center" valign="center" style="BgsPlayerCard" substyle="BgPlayerCard" />
			<quad posn="3 0 31" sizen="8 8" halign="center" valign="center" style="Icons64x64_1" substyle="CameraLocal" />
			<label posn="10 0.5 31" scale="1" halign="center" valign="center" text="0" id="SpecCount2" />
			<label posn="0 -5 31"  scale="0.6" valign="center" text="{{{TargetC}}}Target" id="SpecTarget" />
			<label posn="0 -7 31"  scale="0.6" valign="center" text="{{{FreeC}}}Free" id="SpecFree" scriptevents="1"/>
			<label posn="0 -9 31" scale="0.6" valign="center" text="{{{OverviewC}}}Overview" id="SpecOverview" scriptevents="1" />
		</frame>
	""";
		return ML;
}
declare Ident[Integer] Spawns;
CSmBlockSpawn GetSpawn(Ident id) {
	foreach (BlockSpawn in BlockSpawns) {
		if (BlockSpawn.Id == id) {
			declare CSmBlockSpawn Spawn <=> BlockSpawn;
			return Spawn;
		}
	}
	return Null;
}
declare Ident[Integer] CPs;
CSmBlockPole GetCP(Ident id) {
	foreach (BlockPole in BlockPoles) {
		if (BlockPole.Id == id) {
			declare CSmBlockPole Pole <=> BlockPole;
			return Pole;
		}
	}
	return Null;
}

Void PlayerElimSound(Ident PId, CUIConfig UI) {
	UI.SendNotice("", CUIConfig::ENoticeLevel::Default, Null, CUIConfig::EAvatarVariant::Default, CUIConfig::EUISound::PlayerEliminated, 0);
}

main() {
	UseClans = False;	
	UsePvPCollisions = False;
	UsePvPWeapons = False;
		
	/* ------------------------------------- */
	declare LayerSpawnQueue		<=> UIManager.UILayerCreate();
	declare LayerScoresTable	<=> UIManager.UILayerCreate();
	declare LayerInfos			<=> UIManager.UILayerCreate();
	declare LayerTops			<=> UIManager.UILayerCreate();
	declare LayerScreen			<=> UIManager.UILayerCreate();
	LayerScoresTable.Type = CUILayer::EUILayerType::ScoresTable;
	LayerScreen.Type = CUILayer::EUILayerType::ScreenIn3d;
	UIManager.UIAll.ScoreTableOnlyManialink = True;
	UIManager.UIAll.ScoreTable = "";
	UIManager.UIAll.SmallScoreTable = "";
	while (!ServerShutdownRequested) {
		LoadMap();
		UIManager.UIAll.StatusMessage = "Please wait...";
		Score::MatchBegin();
		
		declare MapWinnerId = NullId;
		MatchEndRequested = False;
		
		UIManager.UIAll.UISequence = CUIConfig::EUISequence::Intro;
		UIManager.UIAll.BigMessage = "";
		//wait(UIManager.UIAll.UISequenceIsCompleted);
		UIManager.UIAll.BigMessage = "";
		UIManager.UIAll.StatusMessage = "";
		UIManager.UIAll.ScoreTableOnlyManialink = True;
		UIManager.UIAll.OverlayHideRoundScores = True;
		
		declare Integer EndAt;
		
		XmlRpc.SendCallback("MapLoaded", """{}""");
		
		while (!MatchEndRequested && !ServerShutdownRequested) {
			// Match start
			UIManager.ResetAll();		
			SM::SetupDefaultVisibility();
			UIManager.UIAll.UISequence = CUIConfig::EUISequence::Playing;	
			Score::RoundBegin();
			UIManager.UIAll.CountdownEndTime = Now+MatchTime;
		
			StartTime = Now;
			EndTime = Now+MatchTime;
			EndAt = Now+MatchTime;

			foreach (Score in Scores) {
				declare Integer PoleBonus for Score;
				declare Integer SurvivalBonus for Score;
				declare Integer HitBonus for Score;
				PoleBonus = 0;
				SurvivalBonus = 0;
				HitBonus = 0;
				Score.RoundPoints = 0;
			}
			foreach (Player in Players) {
				declare Integer RoundHits for Player;
				RoundHits = 0;
				if (Player.Score != Null) Player.Score.RoundPoints = 1;
				declare Integer CP for Player;
				declare Integer BestTime for Player;
				declare Integer BestResp for Player;
				declare Integer[] CPTimes for Player;
				declare Integer[] CPTimesC for Player;
				declare Boolean Training for Player = False;
				Training = False;
				CP = 1;
				BestTime = 0;
				BestResp = 0;
				CPTimes.clear();
				CPTimesC.clear();
			}
			
			UIManager.UIAll.UILayers.clear();
			UIManager.UIAll.UILayers.add(LayerSpawnQueue);
			UIManager.UIAll.UILayers.add(LayerScoresTable);
			UIManager.UIAll.UILayers.add(LayerInfos);
			UIManager.UIAll.UILayers.add(LayerScreen);
			declare RoundEndRequested = False;
			declare RoundWinnerId = NullId;
			declare LastSpawnTime = -SpawnInterval * 1000;
			declare LastMessageTime = Now;
			declare LastUIUpdateTime = -C_UITickPeriod;
			LayerScoresTable.ManialinkPage = MLGet_ScoreTable(False);
			LayerScreen.ManialinkPage = MLGet_SpawnScreen(MapName, Map.AuthorNickName);
				
			StartTime = Now;
			---EndTime---
			EndTime = -1;
			UIManager.UIAll.CountdownEndTime = Now+MatchTime;
			
			declare Integer MaxCPs = 0;
			declare SClan = 0;
			Spawns.clear();
			foreach (BlockSpawn in BlockSpawns) {
				if (BlockSpawn.Order == 0) continue;
				Spawns[BlockSpawn.Order] = BlockSpawn.Id;
				BlockSpawn.Base.IsActive = True;
			}
			CPs.clear();
			declare Errors = False;
			//declare CSmBlockPole[Integer] CPs;
			declare CClan = 1;
			foreach (BlockPole in BlockPoles) {
				if (BlockPole.Order == 0) continue;
				BlockPole.Gauge.Value = 1;
				BlockPole.Gauge.Max = 1;
				CPs[BlockPole.Order] = BlockPole.Id;
				declare Integer CheckSpawn = BlockPole.Order;
				while (Spawns.existskey(BlockPole.Order) == False) {
					if (Spawns.existskey(CheckSpawn))
						Spawns[BlockPole.Order] = Spawns[CheckSpawn];
					CheckSpawn -= 1;
					if (CheckSpawn < 0) {
						Errors = True;
						UIManager.UIAll.SendChat("[ERROR] Failed to parse MapType. - Can not attach any checkpoint to pole #"^BlockPole.Order^".");
						break;
					}
				}
				MaxCPs += 1;
			}
			if (!Spawns.existskey(1)) {
				Errors = True;
				UIManager.UIAll.SendChat("[ERROR] Failed to parse MapType. - No startpoint found (#1).");
				break;
			}
			if (!CPs.existskey(1)) {
				Errors = True;
				UIManager.UIAll.SendChat("[ERROR] Failed to parse MapType. - No finish found (#1).");
				break;
			}
			for (i, 1, MaxCPs) {
				if (CPs.existskey(i)) {
					// {todo} Ability to disable this check since some servers might want to use this technique.
					if (Spawns.existskey(i) && i != 1) { // ignore check if spawn/finish
						declare CSmBlockPole cpp <=> GetCP(CPs[i]);
						declare CSmBlockSpawn cps <=> GetSpawn(CPs[i]);
						/*declare Real dist = 	(cpp.Position.X - cps.Position.X) +
												(cpp.Position.Y - cps.Position.Y) +
												(cpp.Position.Z - cps.Position.Z);
						if (dist < 0) dist = dist * -1;
						if (dist > 30) {
							Errors = True;
							UIManager.UIAll.SendChat("[ERROR] Failed to parse MapType. - Checkpoint and spawn of #"^i^" are placed "^dist^" blockunits (XYZ) from eachother which is quite far in order to be correct.");
							break;
						}*/
					} // else: previous spawnpoint, checked before.
				} else {
					Errors = True;
					UIManager.UIAll.SendChat("[ERROR] Failed to parse MapType. - Failed to find the next checkpoint (#"^i^"), or end is not detected.");
					break;
				}
				if (Spawns.existskey(i) && !CPs.existskey(i)) {
					Errors = True;
					UIManager.UIAll.SendChat("[ERROR] Failed to parse MapType. - Cannot attach spawnpoint #"^i^" to a checkpoint.");
					break;
				}
			}
			
			while (!RoundEndRequested && !MatchEndRequested && !ServerShutdownRequested) 
			{
				if (Errors) { // Easier way to do it here, skips a huge if-clause/annoying tabs
					UIManager.UIAll.SendChat("[ERROR] Map start aborted.");
					break;
				}
				yield;
				UIManager.UIAll.ScoreTableOnlyManialink = True;
				foreach (Player in Players) {
					declare UI <=> UIManager.GetUI(Player);
					if (UI == Null)
						continue;
					declare Integer RespawnDelay for Player;
					declare Integer SpawnReq for Player;
					declare Integer CP for Player;
					declare Integer SurrenderQ for Player = 0;
					declare Boolean AlwaysFF for Player = False;
					declare Integer[] CPTimesC for Player;
					declare Boolean Training for Player = False;
					if (Player.SpawnStatus == CSmPlayer::ESpawnStatus::NotSpawned || SpawnReq != 0) {
						declare Integer StartTime for Player;
						declare Integer BestTime for Player;
						declare Integer Respawns for Player;
						declare Boolean ResetTimer for Player;
						declare UI <=> UIManager.GetUI(Player);
						if (CP < 1)
							CP = 1;
						if (SpawnReq == 1) {
							if (UI != Null) {
								UI.SendNotice("", CUIConfig::ENoticeLevel::Default, Null, CUIConfig::EAvatarVariant::Default, CUIConfig::EUISound::EndMatch , 0);
								foreach (Playerr in Spectators) {
									declare UII <=> UIManager.GetUI(Playerr);
									if (UII == Null) continue;
									if (UII.SpectatorForcedTarget == Player.Id && UII.SpectatorForceCameraType == 1) {
										UII.SendNotice("", CUIConfig::ENoticeLevel::Default, Null, CUIConfig::EAvatarVariant::Default, CUIConfig::EUISound::EndMatch, 0);
									}
								}
							}
						}
						SpawnReq = 0;
						RespawnDelay = 0;
						if (Training) {
							StartTime = Now+2500;
							declare netwrite Net_Resp for UI = 0;
							Net_Resp = Respawns;
							declare netwrite Net_StartTime for UI = 0;
							Net_StartTime = StartTime;
						}
						if (CP != 1 && !AlwaysFF) {
							SM::SpawnPlayer(Player, 0, GetSpawn(Spawns[CP]), Now-2000);
							Player.ArmorMax = 1000;
							Player.Armor = 1000;
							RespawnDelay = Now + 5000;
							declare Integer LatestRespAdd for Player = 0;
							if (Now - LatestRespAdd > 1000) {
								LatestRespAdd = Now;
								Respawns += 1;
							}
							declare netwrite Net_Resp for UI = 0;
							Net_Resp = Respawns;
							declare netwrite Net_Copilot for UI = 0;
							declare netwrite Net_CopilotTime for UI = 0;
							declare Dir = GetSpawn(Spawns[CP]).DirFront - GetCP(CPs[CP]).DirFront;
							declare Boolean IsZ = GetSpawn(Spawns[CP]).DirFront.Z == 0;
							if (Dir.X == 0.0 && Dir.Z == 0.0) Net_Copilot = 0;
							else if (Dir.X == Dir.Z && IsZ) Net_Copilot = 1;
							else if (Dir.X != Dir.Z && IsZ) Net_Copilot = 2;
							else if (Dir.X != Dir.Z && !IsZ) Net_Copilot = 1;
							else if (Dir.X == Dir.Z && !IsZ) Net_Copilot = 2;
							else Net_Copilot = 3;
							Net_CopilotTime = Now;
							//UI.SendNotice("", CUIConfig::ENoticeLevel::Default, Null, CUIConfig::EAvatarVariant::Default, CUIConfig::EUISound::ScoreProgress, 0);
						} else {
							CP = 1;
							StartTime = Now+3500;
							CPTimesC.clear();
							for (i, 0, MaxCPs)
								CPTimesC.add(0);
							SM::SpawnPlayer(Player, 0, GetSpawn(Spawns[CP]), Now+3500);
							Player.ArmorMax = 1000;
							Player.Armor = 1000;
							ResetTimer = True;
							Respawns = 0;
							declare netwrite Net_Resp for UI = 0;
							Net_Resp = Respawns;
							declare netwrite Net_StartTime for UI = 0;
							Net_StartTime = StartTime;
							//UI.SendNotice("", CUIConfig::ENoticeLevel::Default, Null, CUIConfig::EAvatarVariant::Default, CUIConfig::EUISound::PlayersRemaining, 0);
						}
						XmlRpc.SendCallback("Spawning", """{"Login": "{{{Player.Login}}}", "CpId": {{{CP}}} }""");
					}
					declare netread Integer Net_Surrender for UI = 0;
					declare netread Boolean Net_AlwaysFF for UI = False;
					declare netread Integer Net_TrainingToggleTime for UI = 0;
					declare netread Integer Net_TrainingCP for UI = 0;
					declare Integer TrainingToggleTime for Player = 0;
					declare Integer TrainingCP for Player = 0;
					
					if (Net_Surrender > SurrenderQ && Net_Surrender > 2000)
					{
						SurrenderQ = Net_Surrender;
						SpawnReq = 1;
						if (!Training)
							CP = 1;
						XmlRpc.SendCallback("Surrender", """{"Login": "{{{Player.Login}}}"}""");
					}
					declare forceCPswap = False;
					if (Net_TrainingToggleTime > TrainingToggleTime && Net_TrainingToggleTime > 2000 && Now - Net_TrainingToggleTime > 0 && Now - Net_TrainingToggleTime < 2000 )
					{
						TrainingToggleTime = Net_TrainingToggleTime;
						Training = !Training;
						//log("TOGGLE");
						CP = 0;
						SpawnReq = 1;
						forceCPswap = True;
					}
					if (Training) {
						if (Net_TrainingCP != TrainingCP || forceCPswap) {
							if (Net_TrainingCP <= MaxCPs && Net_TrainingCP >= 0) {
								TrainingCP = Net_TrainingCP;
								CP = TrainingCP;
								SpawnReq = 1;
							}
						}
					}
					if (Net_AlwaysFF != AlwaysFF) {
						AlwaysFF = Net_AlwaysFF;
						if (Training)
							AlwaysFF = False;
						else {
						if (AlwaysFF)
							UI.SendNotice("You will now always respawn at the start.", CUIConfig::ENoticeLevel::Default, Null, CUIConfig::EAvatarVariant::Default, CUIConfig::EUISound::Notice, 0);
						else
							UI.SendNotice("You will now respawn at your passed checkpoints.", CUIConfig::ENoticeLevel::Default, Null, CUIConfig::EAvatarVariant::Default, CUIConfig::EUISound::Notice, 0);
						}
					}
					if (Training)
						AlwaysFF = False;
					if (Player.BlockPole != Null && SpawnReq != 1) {
						declare Integer CP for Player;
						declare Integer BestTime for Player;
						declare Integer StartTime for Player;
						declare Integer Respawns for Player;
						declare Integer BestResp for Player;
						declare Integer[] CPTimes for Player;
						if (Training) { // don't count
							if (MaxCPs == CP && Player.BlockPole.Order == 1 || Player.BlockPole.Order - 1 == CP) {
								declare Integer StartTime for Player;
								declare Text tdiff = "$999+0:00.000";
								/*if (CPTimes.existskey(CP)) {
									declare Integer diff = (Now-StartTime)-CPTimes[CP];
									if (diff > 0)
										tdiff = "$f44+"^GetTime2(diff);
									else if (diff < 0)
										tdiff = "$4f4-"^GetTime2(diff*-1);
								}
								CPTimesC[CP] = (Now-StartTime);*/
								UI.SendNotice("", CUIConfig::ENoticeLevel::Default, Null, CUIConfig::EAvatarVariant::Default, CUIConfig::EUISound::Checkpoint, 0);
								declare netwrite Net_CpInfo1 for UI = "";
								declare netwrite Net_CpInfo2 for UI = "";
								declare netwrite Net_CpInfo3 for UI = "";
								declare netwrite Net_CpInfoTime for UI = 0;
								Net_CpInfo1 = "$s$i$08fTraining finish";
								Net_CpInfo2 = "$o$s$fff"^GetTime(StartTime);
								Net_CpInfo3 = "$o$s"^tdiff;
								Net_CpInfoTime = Now;
								foreach (Playerr in Spectators) {
									declare UII <=> UIManager.GetUI(Playerr);
									if (UII == Null) continue;
									if (UII.SpectatorForcedTarget == Player.Id && UII.SpectatorForceCameraType == 1) {
										UII.SendNotice("", CUIConfig::ENoticeLevel::Default, Null, CUIConfig::EAvatarVariant::Default, CUIConfig::EUISound::Checkpoint, 0);
										declare netwrite Net_CpInfo1 as Net_CpInfo1r for UII = "";
										declare netwrite Net_CpInfo2 as Net_CpInfo2r for UII = "";
										declare netwrite Net_CpInfo3 as Net_CpInfo3r for UII = "";
										declare netwrite Net_CpInfoTime as Net_CpInfoTimer for UII = 0;
										Net_CpInfo1r = "$s$i$08fTraining finish";
										Net_CpInfo2r = "$o$s$fff"^GetTime(StartTime);
										Net_CpInfo3r = "$o$s"^tdiff;
										Net_CpInfoTimer = Now;
									}
								}
								SpawnReq = 1;
							}
						} else if (Player.BlockPole.Order - 1 == CP)
						{
							CP = Player.BlockPole.Order;
							declare Integer StartTime for Player;
							declare Text tdiff = "$999+0:00.000";
							if (CPTimes.existskey(CP)) {
								declare Integer diff = (Now-StartTime)-CPTimes[CP];
								if (diff > 0)
									tdiff = "$f44+"^GetTime2(diff);
								else if (diff < 0)
									tdiff = "$4f4-"^GetTime2(diff*-1);
							}
							CPTimesC[CP] = (Now-StartTime);
							UI.SendNotice("", CUIConfig::ENoticeLevel::Default, Null, CUIConfig::EAvatarVariant::Default, CUIConfig::EUISound::Checkpoint, 0);
							declare netwrite Net_CpInfo1 for UI = "";
							declare netwrite Net_CpInfo2 for UI = "";
							declare netwrite Net_CpInfo3 for UI = "";
							declare netwrite Net_CpInfoTime for UI = 0;
							Net_CpInfo1 = "$s$i$08fCheckpoint "^(CP-1);
							Net_CpInfo2 = "$o$s$fff"^GetTime(StartTime);
							Net_CpInfo3 = "$o$s"^tdiff;
							Net_CpInfoTime = Now;
							foreach (Playerr in Spectators) {
								declare UII <=> UIManager.GetUI(Playerr);
								if (UII == Null) continue;
								if (UII.SpectatorForcedTarget == Player.Id && UII.SpectatorForceCameraType == 1) {
									UII.SendNotice("", CUIConfig::ENoticeLevel::Default, Null, CUIConfig::EAvatarVariant::Default, CUIConfig::EUISound::Checkpoint, 0);
									declare netwrite Net_CpInfo1 as Net_CpInfo1r for UII = "";
									declare netwrite Net_CpInfo2 as Net_CpInfo2r for UII = "";
									declare netwrite Net_CpInfo3 as Net_CpInfo3r for UII = "";
									declare netwrite Net_CpInfoTime as Net_CpInfoTimer for UII = 0;
									Net_CpInfo1r = "$s$i$08fCheckpoint "^(CP-1);
									Net_CpInfo2r = "$o$s$fff"^GetTime(StartTime);
									Net_CpInfo3r = "$o$s"^tdiff;
									Net_CpInfoTimer = Now;
								}
							}
							XmlRpc.SendCallback("Checkpoint", """{"Login": "{{{Player.Login}}}", "CpId": {{{CP}}}, "CpTime": {{{CPTimesC[CP]}}} }""");
						} else if (MaxCPs == CP && Player.BlockPole.Order == 1 && SpawnReq == 0) { // latest = prevent training "hack"
							declare Integer PrevTime = 100000000-Player.Score.Points;
							BestTime = (Now-StartTime);
							declare Integer Sc = 100000000-BestTime;
							if (Sc < 0)
								Sc = 0;
							if (Sc > Player.Score.Points) {
								Player.Score.Points = Sc;
								BestResp = Respawns;
								CPTimes.clear();
								for(i, 1, CPTimesC.count) {
									CPTimes.add(CPTimesC[i-1]);
								}
							}
							declare UI <=> UIManager.GetUI(Player);
							declare ClRank = 1;
							declare ExitNow = False;
							foreach (Score in Scores) {
								foreach (Player in Players) {
									if (Score.Points != Player.Score.Points)
										ClRank += 1;
									else {
										ExitNow = True;
										break;
									}
								}
								if (ExitNow)
									break;
							}
							declare Text tdiff = "$999+0:00.000";
							if (PrevTime != 100000000) {
								declare Integer diff = (Now-StartTime)-PrevTime;
								if (diff > 0)
									tdiff = "$f44+"^GetTime2(diff);
								else if (diff < 0)
									tdiff = "$4f4-"^GetTime2(diff*-1);
							}
							UI.SendNotice("", CUIConfig::ENoticeLevel::Default, Null, CUIConfig::EAvatarVariant::Default, CUIConfig::EUISound::VictoryPoint, 0);
							declare netwrite Net_CpInfo1 for UI = "";
							declare netwrite Net_CpInfo2 for UI = "";
							declare netwrite Net_CpInfo3 for UI = "";
							declare netwrite Net_CpInfoTime for UI = 0;
							Net_CpInfo1 = "$s$i$08fFinished";
							Net_CpInfo2 = "$o$s$fff"^GetTime(StartTime);
							Net_CpInfo3 = "$o$s"^tdiff;
							Net_CpInfoTime = Now;
							foreach (Playerr in Spectators) {
								declare UII <=> UIManager.GetUI(Playerr);
								if (UII == Null) continue;
								if (UII.SpectatorForcedTarget == Player.Id && UII.SpectatorForceCameraType == 1) {
									UII.SendNotice("", CUIConfig::ENoticeLevel::Default, Null, CUIConfig::EAvatarVariant::Default, CUIConfig::EUISound::VictoryPoint, 0);
									declare netwrite Net_CpInfo1 as Net_CpInfo1r for UII = "";
									declare netwrite Net_CpInfo2 as Net_CpInfo2r for UII = "";
									declare netwrite Net_CpInfo3 as Net_CpInfo3r for UII = "";
									declare netwrite Net_CpInfoTime as Net_CpInfoTimer for UII = 0;
									Net_CpInfo1r = "$s$i$08fFinished";
									Net_CpInfo2r = "$o$s$fff"^GetTime(StartTime);
									Net_CpInfo3r = "$o$s"^tdiff;
									Net_CpInfoTimer = Now;
								}
							}
							UIManager.UIAll.SendNotice(
								"$s$08f"^GetTime(StartTime)^"$z$fff$o ["^Respawns^"] - (#"^ClRank^")$o "^Player.Name,	
								CUIConfig::ENoticeLevel::PlayerInfo, 
								Player.User, CUIConfig::EAvatarVariant::Default, 
								CUIConfig::EUISound::Finish, 0
							);
							declare Text CPstr = "";
							for (i, 0, CPTimesC.count-1) {
								CPstr ^= CPTimesC[i]^"";
								if (i != CPTimesC.count-1)
									CPstr ^= ",";
							}
							XmlRpc.SendCallback("Finished", """{"Login": "{{{Player.Login}}}", "Score": {{{(""^BestTime)}}}, "CPs": "{{{CPstr}}}"}""");
							CP = 1;
							declare Boolean ResetTimer for Player;
							declare netwrite Net_Resp for UI = 0;
							Net_Resp = 0;
							Respawns = 0;
							ResetTimer = True;
							SM::SpawnPlayer(Player, 0, GetSpawn(Spawns[CP]), Now+4000);
							XmlRpc.SendCallback("Spawning", """{"Login": "{{{Player.Login}}}", "CpId": {{{CP}}} }""");
							StartTime = Now+4000;
							declare netwrite Net_StartTime for UI = 0;
							Net_StartTime = StartTime;
							if (BestTime < Player.SoloTime)
								Player.SoloTime = BestTime;
							LayerScoresTable.ManialinkPage = MLGet_ScoreTable(False);
						}
					}
				}
					
				foreach (Event in PendingEvents) {
					if (Event.Type == CSmModeEvent::EType::OnArmorEmpty) {
						declare Integer SpawnReq for Event.Victim;
						if (SpawnReq != 1) {
							SpawnReq = 1;
						}
						LayerScoresTable.ManialinkPage = MLGet_ScoreTable(False);					
						Discard(Event);
					} else if (Event.Type == CSmModeEvent::EType::OnCapture ) {
						LayerScoresTable.ManialinkPage = MLGet_ScoreTable(False);
						PassOn(Event);
					} else if (Event.Type == CSmModeEvent::EType::OnPlayerRequestRespawn) {
						declare Integer SpawnReq for Event.Player;
						SpawnReq = 1;
						Discard(Event);
					} else if (Event.Type == CSmModeEvent::EType::OnHit) {
						Discard(Event);
					} else {
						PassOn(Event);
					}
				}	
				
				/* ------------------------------------- */
				if (LastMessageTime >= 0 && LastMessageTime + 3000 < Now) {
					UIManager.UIAll.BigMessage = "";
				}
				if (LastUIUpdateTime + C_UITickPeriod < Now) {
					LayerInfos.ManialinkPage = MLGet_Info();
					LayerScoresTable.ManialinkPage = MLGet_ScoreTable(False);
					LastUIUpdateTime = Now;
					
					declare UsedLayers = Ident[];
					foreach (Player in Players) {
						declare UI <=> UIManager.GetUI(Player);
						if (UI == Null) continue;
						// Kill ghost cam
						UI.SpectatorForceCameraType = 0;
						UI.SpectatorForcedTarget = NullId;
								
						declare CUILayer LayerSpawnScreen;
						declare Boolean ResetTimer for Player;
						declare Boolean Training for Player = False;
						
						if (UI.UILayers.count != 1 || ResetTimer) {
							ResetTimer = False;
							UI.UILayers.clear();
							LayerSpawnScreen <=> UIManager.UILayerCreate();
							LayerSpawnScreen.Type = CUILayer::EUILayerType::Normal;
							UI.UILayers.add(LayerSpawnScreen);
						} else {
							LayerSpawnScreen <=> UI.UILayers[0];
						}
						UsedLayers.add(LayerSpawnScreen.Id);
												
						declare Integer CP for Player;
						
						LayerSpawnScreen.ManialinkPage = MLGet_Gui(0, MaxCPs, Training, False, CP);
						
						if (CPs.existskey(CP+1)) {
							declare CSmBlockPole cpp <=> GetCP(CPs[CP+1]);
							UI.Hud3dMarkers = """
							<marker label="$o$fffCP{{{CP}}}" pos="{{{ cpp.Position[0] }}} {{{ cpp.Position[1] + 3 }}} {{{ cpp.Position[2] }}}" />
							""";
						} else {
							declare CSmBlockPole cpp <=> GetCP(CPs[1]);
							UI.Hud3dMarkers = """
							<marker label="$o$fffFinish" pos="{{{ cpp.Position[0] }}} {{{ cpp.Position[1] + 3 }}} {{{ cpp.Position[2] }}}" />
							""";
						}
						declare Integer StartTime for Player;
						declare Integer BestTime for Player;
						declare Integer RespawnDelay for Player;
						if (CP < 2)
							CP = 1;
						if (StartTime < 2)
							StartTime = Now;
						declare Text AddText = "";
						if (RespawnDelay > Now && !Training) {
							if (Player.SpawnStatus == CSmPlayer::ESpawnStatus::Spawning)
								UI.StatusMessage = "CP: "^CP-1^"/"^(MaxCPs-1);
							else
								UI.StatusMessage = "$fffPress $aaaF3 $fffto restart from the beginning.";
						} else if (Player.SpawnStatus == CSmPlayer::ESpawnStatus::Spawning)
							//UI.StatusMessage = """Total CPs: """^(MaxCPs-1);
							UI.StatusMessage = "";
						else
							UI.StatusMessage = "";
							
						declare Text[] Names;
						foreach (Playerr in Spectators) {
							declare UII <=> UIManager.GetUI(Playerr);
							if (UII == Null) continue;
							if (UII.SpectatorForcedTarget == Player.Id && UII.SpectatorForceCameraType == 1) 
								Names.add(Playerr.Name);
						}
						declare netwrite Net_SpecCount for UI = 0;
						Net_SpecCount = Names.count;
						declare netread Net_SpecWhoReq for UI = 0;
						declare Net_SpecWho for Player = 0;
						if (Net_SpecWhoReq != Net_SpecWho) {
							Net_SpecWho = Net_SpecWhoReq;
							if (Names.count == 0)
								UI.SendChat("$o$fffSpectators: $oNobody.");
							else {
								declare Text SendText = "$o$fffSpectators:$z";
								foreach (Specr in Names)
									SendText ^= " "^Specr^"$z";
								UI.SendChat(SendText);
							}
						}
						foreach (Playerr in Spectators) {
							declare UII <=> UIManager.GetUI(Playerr);
							if (UII == Null) continue;
							if (UII.SpectatorForcedTarget == Player.Id && UII.SpectatorForceCameraType == 1) 
							{
								declare netwrite Net_SpecCount as Net_SpecCount2 for UII = 0; 
								Net_SpecCount2 = Names.count;
								//log("set");
							}
						}
					}
					foreach (Player in Spectators) {
						declare UI <=> UIManager.GetUI(Player);
						if (UI == Null) continue;
						declare netread Net_SpecTargetReq for UI = "";
						declare netread Integer Net_SpecTargetCn for UI = 0;
						declare SpecTarget for Player = 0;
						if (Net_SpecTargetCn != SpecTarget && Net_SpecTargetReq != "") {
							SpecTarget = Net_SpecTargetCn;
							if (SpecTarget != 0) {
								foreach (Playerr in Players) {
									if (Playerr.Login == Net_SpecTargetReq) {
										UI.SpectatorForcedTarget = Playerr.Id;
										UI.SpectatorForceCameraType = 1;
									}
								}
							}
						}
						declare Ident GetUIFor = NullId;
						if (UI.SpectatorAutoTarget != NullId)
							GetUIFor = UI.SpectatorAutoTarget;
						if (UI.SpectatorForcedTarget != NullId)
							GetUIFor = UI.SpectatorForcedTarget;
						declare CUILayer LayerSpawnScreen;
						if (UI.UILayers.count != 1) {
							UI.UILayers.clear();
							LayerSpawnScreen <=> UIManager.UILayerCreate();
							LayerSpawnScreen.Type = CUILayer::EUILayerType::Normal;
							UI.UILayers.add(LayerSpawnScreen);
						} else {
							LayerSpawnScreen <=> UI.UILayers[0];
						}
						declare Boolean SetToDefault = True;
						if (GetUIFor != NullId && Net_SpecTargetReq != "") {
							foreach (Playerr in Players)
							{
								if (Playerr.Id == GetUIFor) {
									declare Boolean Training for Playerr = False;
									declare Integer CP for Playerr = 0;
									LayerSpawnScreen.ManialinkPage = MLGet_Gui(1, MaxCPs, Training, False, CP);
									UsedLayers.add(LayerSpawnScreen.Id);
									declare Integer StartTime for Playerr;
									declare Integer Respawns for Playerr;
									declare netwrite Net_Resp for UI = 0;
									declare netwrite Net_StartTime for UI = 0;
									Net_Resp = Respawns;
									Net_StartTime = StartTime;
									SetToDefault = False;
									break;
								}
							}
						} 
						if (SetToDefault) {
							declare netread Net_SpecTypePref for UI = 0;
							if (Net_SpecTypePref == 1) {
								UI.SpectatorForceCameraType = 2;
								LayerSpawnScreen.ManialinkPage = MLGet_Gui(3, MaxCPs, False, False, 0);
							} else {
								UI.SpectatorForceCameraType = 0;
								UI.SpectatorForcedTarget = NullId;
								LayerSpawnScreen.ManialinkPage = MLGet_Gui(2, MaxCPs, False, False, 0);
							}
							UsedLayers.add(LayerSpawnScreen.Id);
						}
					}
					declare LayersToRemove = Ident[];
					foreach (Layer in UIManager.UIAll.UILayers) { UsedLayers.add(Layer.Id); }
					UsedLayers.add(LayerSpawnQueue.Id);UsedLayers.add(LayerScoresTable.Id);
					UsedLayers.add(LayerInfos.Id);UsedLayers.add(LayerTops.Id);
					foreach (Layer in UIManager.UILayers) {
						if (!UsedLayers.exists(Layer.Id)) {
							LayersToRemove.add(Layer.Id);
						}
					}
					foreach (LayerId in LayersToRemove) {
						UIManager.UILayerDestroy(UIManager.UILayers[LayerId]);
					}
				}
				if (Now > EndAt)
					break;
			}
			LayerScoresTable.ManialinkPage = MLGet_ScoreTable(False);
			foreach (Player in Players) {
				declare UI <=> UIManager.GetUI(Player);
				if (UI == Null) continue;
				if (UI.UILayers.count == 1) {
					declare CUILayer LayerSpawnScreen;
					LayerSpawnScreen <=> UI.UILayers[0];
					LayerSpawnScreen.ManialinkPage = "";
				}
			}
			// Round end
			UIManager.UIAll.CountdownEndTime = 0;
			
			OffZoneRadius = -1.;
			StartTime = -1;
			EndTime = -1;
			SM::UnspawnAllPlayers();
			UIManager.UIAll.UISequence = CUIConfig::EUISequence::EndRound;
			UIManager.UIAll.ScoreTableVisibility = CUIConfig::EVisibility::ForcedVisible;
			XmlRpc.SendCallback("RoundEnded", """{}"""); // {todo} Scoreboard
			//sleep(500);
			Score::RoundEnd();
			//sleep(1000);
			UIManager.UIAll.CountdownEndTime = Now+20000;
			UIManager.UIAll.BigMessage = "";
			
			// {todo} Multiple rounds/rounds mode
			// Just quit the round now, effectively ending the match.
			break;
		}
		// Match end
		Score::MatchEnd(True);	
		declare Text Output = "{";
		foreach (Score in Scores) {
			if (Score.Points != 0 && Score.Points != 100000000) {
				if (Output != "{") 
					Output ^= ",";
				Output ^= "\""^Score.User.Login^"\":"^100000000-Score.Points;
			}
		}
		XmlRpc.SendCallback("MatchEnded", Output^"}"); 
		UIManager.UIAll.ScoreTableOnlyManialink = True;
		UIManager.UIAll.OverlayHideRoundScores = True;
		UIManager.UIAll.UISequence = CUIConfig::EUISequence::Outro;	
		//UIManager.UIAll.BigMessage = "Match ended";
		UIManager.UIAll.ScoreTableVisibility = CUIConfig::EVisibility::ForcedVisible;	
		LayerScoresTable.ManialinkPage = MLGet_ScoreTable(False);
		sleep(2000);
		LayerScoresTable.ManialinkPage = MLGet_ScoreTable(True);
		UIManager.UIAll.UISequence = CUIConfig::EUISequence::Podium;	
		UIManager.UIAll.UILayers.add(LayerTops); 
		//wait(UIManager.UIAll.UISequenceIsCompleted);
		//sleep(1000);
		wait(UIManager.UIAll.CountdownEndTime < Now);
		UIManager.UIAll.BigMessage = "";
		UIManager.UIAll.UILayers.clear();	
		UnloadMap();		
	}
	// Server end
	UIManager.UILayerDestroy(LayerSpawnQueue);
	UIManager.UILayerDestroy(LayerScoresTable);
	UIManager.UILayerDestroy(LayerInfos);
	UIManager.UILayerDestroy(LayerTops);
}